quickshell and hyprland additions

2026-04-11 09:36:46 +00:00 · 2026-03-15 13:56:00 +02:00
parent c9c27d1554
commit 1ad06b82a6
509 changed files with 68371 additions and 19 deletions
--- a/.config/quickshell/caelestia/modules/dashboard/Wrapper.qml
+++ b/.config/quickshell/caelestia/modules/dashboard/Wrapper.qml
@@ -0,0 +1,105 @@
+pragma ComponentBehavior: Bound
+
+import qs.components
+import qs.components.filedialog
+import qs.config
+import qs.utils
+import Caelestia
+import Quickshell
+import QtQuick
+
+Item {
+    id: root
+
+    required property PersistentProperties visibilities
+    readonly property PersistentProperties dashState: PersistentProperties {
+        property int currentTab
+        property date currentDate: new Date()
+
+        reloadableId: "dashboardState"
+    }
+    readonly property FileDialog facePicker: FileDialog {
+        title: qsTr("Select a profile picture")
+        filterLabel: qsTr("Image files")
+        filters: Images.validImageExtensions
+        onAccepted: path => {
+            if (CUtils.copyFile(Qt.resolvedUrl(path), Qt.resolvedUrl(`${Paths.home}/.face`)))
+                Quickshell.execDetached(["notify-send", "-a", "caelestia-shell", "-u", "low", "-h", `STRING:image-path:${path}`, "Profile picture changed", `Profile picture changed to ${Paths.shortenHome(path)}`]);
+            else
+                Quickshell.execDetached(["notify-send", "-a", "caelestia-shell", "-u", "critical", "Unable to change profile picture", `Failed to change profile picture to ${Paths.shortenHome(path)}`]);
+        }
+    }
+
+    readonly property real nonAnimHeight: state === "visible" ? (content.item?.nonAnimHeight ?? 0) : 0
+
+    visible: height > 0
+    implicitHeight: 0
+    implicitWidth: content.implicitWidth
+
+    onStateChanged: {
+        if (state === "visible" && timer.running) {
+            timer.triggered();
+            timer.stop();
+        }
+    }
+
+    states: State {
+        name: "visible"
+        when: root.visibilities.dashboard && Config.dashboard.enabled
+
+        PropertyChanges {
+            root.implicitHeight: content.implicitHeight
+        }
+    }
+
+    transitions: [
+        Transition {
+            from: ""
+            to: "visible"
+
+            Anim {
+                target: root
+                property: "implicitHeight"
+                duration: Appearance.anim.durations.expressiveDefaultSpatial
+                easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
+            }
+        },
+        Transition {
+            from: "visible"
+            to: ""
+
+            Anim {
+                target: root
+                property: "implicitHeight"
+                easing.bezierCurve: Appearance.anim.curves.emphasized
+            }
+        }
+    ]
+
+    Timer {
+        id: timer
+
+        running: true
+        interval: Appearance.anim.durations.extraLarge
+        onTriggered: {
+            content.active = Qt.binding(() => (root.visibilities.dashboard && Config.dashboard.enabled) || root.visible);
+            content.visible = true;
+        }
+    }
+
+    Loader {
+        id: content
+
+        anchors.horizontalCenter: parent.horizontalCenter
+        anchors.bottom: parent.bottom
+
+        visible: false
+        active: true
+
+        sourceComponent: Content {
+            visibilities: root.visibilities
+            state: root.dashState
+            facePicker: root.facePicker
+        }
+    }
+}