quickshell and hyprland additions

2026-04-11 17:47:09 +00:00 · 2026-03-15 13:56:00 +02:00
parent c9c27d1554
commit 1ad06b82a6
509 changed files with 68371 additions and 19 deletions
--- a/.config/quickshell/caelestia/modules/utilities/cards/Toggles.qml
+++ b/.config/quickshell/caelestia/modules/utilities/cards/Toggles.qml
@@ -0,0 +1,113 @@
+import qs.components
+import qs.components.controls
+import qs.services
+import qs.config
+import qs.modules.controlcenter
+import Quickshell
+import Quickshell.Bluetooth
+import QtQuick
+import QtQuick.Layouts
+
+StyledRect {
+    id: root
+
+    required property var visibilities
+    required property Item popouts
+
+    Layout.fillWidth: true
+    implicitHeight: layout.implicitHeight + Appearance.padding.large * 2
+
+    radius: Appearance.rounding.normal
+    color: Colours.tPalette.m3surfaceContainer
+
+    ColumnLayout {
+        id: layout
+
+        anchors.fill: parent
+        anchors.margins: Appearance.padding.large
+        spacing: Appearance.spacing.normal
+
+        StyledText {
+            text: qsTr("Quick Toggles")
+            font.pointSize: Appearance.font.size.normal
+        }
+
+        RowLayout {
+            Layout.alignment: Qt.AlignHCenter
+            spacing: Appearance.spacing.small
+
+            Toggle {
+                icon: "wifi"
+                checked: Nmcli.wifiEnabled
+                onClicked: Nmcli.toggleWifi()
+            }
+
+            Toggle {
+                icon: "bluetooth"
+                checked: Bluetooth.defaultAdapter?.enabled ?? false
+                onClicked: {
+                    const adapter = Bluetooth.defaultAdapter;
+                    if (adapter)
+                        adapter.enabled = !adapter.enabled;
+                }
+            }
+
+            Toggle {
+                icon: "mic"
+                checked: !Audio.sourceMuted
+                onClicked: {
+                    const audio = Audio.source?.audio;
+                    if (audio)
+                        audio.muted = !audio.muted;
+                }
+            }
+
+            Toggle {
+                icon: "settings"
+                inactiveOnColour: Colours.palette.m3onSurfaceVariant
+                toggle: false
+                onClicked: {
+                    root.visibilities.utilities = false;
+                    root.popouts.detach("network");
+                }
+            }
+
+            Toggle {
+                icon: "gamepad"
+                checked: GameMode.enabled
+                onClicked: GameMode.enabled = !GameMode.enabled
+            }
+
+            Toggle {
+                icon: "notifications_off"
+                checked: Notifs.dnd
+                onClicked: Notifs.dnd = !Notifs.dnd
+            }
+
+            Toggle {
+                icon: "vpn_key"
+                checked: VPN.connected
+                enabled: !VPN.connecting
+                visible: Config.utilities.vpn.provider.some(p => typeof p === "object" ? (p.enabled === true) : false)
+                onClicked: VPN.toggle()
+            }
+        }
+    }
+
+    component Toggle: IconButton {
+        Layout.fillWidth: true
+        Layout.preferredWidth: implicitWidth + (stateLayer.pressed ? Appearance.padding.large : internalChecked ? Appearance.padding.smaller : 0)
+        radius: stateLayer.pressed ? Appearance.rounding.small / 2 : internalChecked ? Appearance.rounding.small : Appearance.rounding.normal
+        inactiveColour: Colours.layer(Colours.palette.m3surfaceContainerHighest, 2)
+        toggle: true
+        radiusAnim.duration: Appearance.anim.durations.expressiveFastSpatial
+        radiusAnim.easing.bezierCurve: Appearance.anim.curves.expressiveFastSpatial
+
+        Behavior on Layout.preferredWidth {
+            Anim {
+                duration: Appearance.anim.durations.expressiveFastSpatial
+                easing.bezierCurve: Appearance.anim.curves.expressiveFastSpatial
+            }
+        }
+    }
+}