quickshell and hyprland additions

2026-04-11 09:36:46 +00:00 · 2026-03-15 13:56:00 +02:00
parent c9c27d1554
commit 1ad06b82a6
509 changed files with 68371 additions and 19 deletions
--- a/.config/quickshell/caelestia/utils/SysInfo.qml
+++ b/.config/quickshell/caelestia/utils/SysInfo.qml
@@ -0,0 +1,88 @@
+pragma Singleton
+
+import qs.config
+import qs.utils
+import Quickshell
+import Quickshell.Io
+import QtQuick
+
+Singleton {
+    id: root
+
+    property string osName
+    property string osPrettyName
+    property string osId
+    property list<string> osIdLike
+    property string osLogo: Qt.resolvedUrl(`${Quickshell.shellDir}/assets/logo.svg`)
+    property bool isDefaultLogo: true
+
+    property string uptime
+    readonly property string user: Quickshell.env("USER")
+    readonly property string wm: Quickshell.env("XDG_CURRENT_DESKTOP") || Quickshell.env("XDG_SESSION_DESKTOP")
+    readonly property string shell: Quickshell.env("SHELL").split("/").pop()
+
+    FileView {
+        id: osRelease
+
+        path: "/etc/os-release"
+        onLoaded: {
+            const lines = text().split("\n");
+
+            const fd = key => lines.find(l => l.startsWith(`${key}=`))?.split("=")[1].replace(/"/g, "") ?? "";
+
+            root.osName = fd("NAME");
+            root.osPrettyName = fd("PRETTY_NAME");
+            root.osId = fd("ID");
+            root.osIdLike = fd("ID_LIKE").split(" ");
+
+            const logo = Quickshell.iconPath(fd("LOGO"), true);
+            if (Config.general.logo === "caelestia") {
+                root.osLogo = Qt.resolvedUrl(`${Quickshell.shellDir}/assets/logo.svg`);
+                root.isDefaultLogo = true;
+            } else if (Config.general.logo) {
+                root.osLogo = Quickshell.iconPath(Config.general.logo, true) || "file://" + Paths.absolutePath(Config.general.logo);
+                root.isDefaultLogo = false;
+            } else if (logo) {
+                root.osLogo = logo;
+                root.isDefaultLogo = false;
+            }
+        }
+    }
+
+    Connections {
+        target: Config.general
+
+        function onLogoChanged(): void {
+            osRelease.reload();
+        }
+    }
+
+    Timer {
+        running: true
+        repeat: true
+        interval: 15000
+        onTriggered: fileUptime.reload()
+    }
+
+    FileView {
+        id: fileUptime
+
+        path: "/proc/uptime"
+        onLoaded: {
+            const up = parseInt(text().split(" ")[0] ?? 0);
+
+            const days = Math.floor(up / 86400);
+            const hours = Math.floor((up % 86400) / 3600);
+            const minutes = Math.floor((up % 3600) / 60);
+
+            let str = "";
+            if (days > 0)
+                str += `${days} day${days === 1 ? "" : "s"}`;
+            if (hours > 0)
+                str += `${str ? ", " : ""}${hours} hour${hours === 1 ? "" : "s"}`;
+            if (minutes > 0 || !str)
+                str += `${str ? ", " : ""}${minutes} minute${minutes === 1 ? "" : "s"}`;
+            root.uptime = str;
+        }
+    }
+}