mirror of
https://github.com/belsabbagh/dotfiles.git
synced 2026-04-11 09:36:46 +00:00
68 lines
2.1 KiB
CMake
68 lines
2.1 KiB
CMake
cmake_minimum_required(VERSION 3.19)
|
|
|
|
if(NOT DEFINED VERSION)
|
|
execute_process(COMMAND git describe --tags --abbrev=0
|
|
WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
|
|
OUTPUT_VARIABLE VERSION
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
)
|
|
|
|
if("${VERSION}" STREQUAL "")
|
|
message(FATAL_ERROR "VERSION is not set and failed to get from git")
|
|
endif()
|
|
endif()
|
|
|
|
if(NOT DEFINED GIT_REVISION)
|
|
execute_process(COMMAND git rev-parse HEAD
|
|
WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
|
|
OUTPUT_VARIABLE GIT_REVISION
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
)
|
|
|
|
if("${GIT_REVISION}" STREQUAL "")
|
|
message(FATAL_ERROR "GIT_REVISION is not set and failed to get from git")
|
|
endif()
|
|
endif()
|
|
|
|
string(REGEX REPLACE "^v" "" VERSION "${VERSION}")
|
|
|
|
project(caelestia-shell VERSION ${VERSION} LANGUAGES CXX)
|
|
|
|
set(CMAKE_CXX_STANDARD 20)
|
|
set(CMAKE_CXX_STANDARD_REQUIRED ON)
|
|
set(CMAKE_CXX_EXTENSIONS OFF)
|
|
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
|
|
|
|
set(DISTRIBUTOR "Unset" CACHE STRING "Distributor")
|
|
set(ENABLE_MODULES "extras;plugin;shell" CACHE STRING "Modules to build/install")
|
|
set(INSTALL_LIBDIR "usr/lib/caelestia" CACHE STRING "Library install dir")
|
|
set(INSTALL_QMLDIR "usr/lib/qt6/qml" CACHE STRING "QML install dir")
|
|
set(INSTALL_QSCONFDIR "etc/xdg/quickshell/caelestia" CACHE STRING "Quickshell config install dir")
|
|
|
|
add_compile_options(
|
|
-Wall -Wextra -Wpedantic -Wshadow -Wconversion
|
|
-Wold-style-cast -Wnull-dereference -Wdouble-promotion
|
|
-Wformat=2 -Wfloat-equal -Woverloaded-virtual
|
|
-Wsign-conversion -Wredundant-decls -Wswitch
|
|
-Wunreachable-code
|
|
)
|
|
|
|
if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
|
|
add_compile_options(-Wunused-lambda-capture)
|
|
endif()
|
|
|
|
if("extras" IN_LIST ENABLE_MODULES)
|
|
add_subdirectory(extras)
|
|
endif()
|
|
|
|
if("plugin" IN_LIST ENABLE_MODULES)
|
|
add_subdirectory(plugin)
|
|
endif()
|
|
|
|
if("shell" IN_LIST ENABLE_MODULES)
|
|
foreach(dir assets components config modules services utils)
|
|
install(DIRECTORY ${dir} DESTINATION "${INSTALL_QSCONFDIR}")
|
|
endforeach()
|
|
install(FILES shell.qml LICENSE DESTINATION "${INSTALL_QSCONFDIR}")
|
|
endif()
|